DOMANDA configurare Mikrotik RouterBoard hAP AC Lite rete ospiti

Maniac145 · 15 Novembre 2023

ho configurato il router con una rete wifi principale e funziona benissimo
ora dovrei dovrei aggiungere una rete ospiti che possa accedere solo ad internet e non alla rete interna, come posso fare?
@r3dl4nce

r3dl4nce · 15 Novembre 2023

Aggiorna alla versione 7.12
Esporta la configurazione senza dati sensibili
Incolla qua sotto tag code

Così la vedo e ti dico come aggiungere WiFi ulteriori

Maniac145 · 15 Novembre 2023

r3dl4nce ha detto:
Aggiorna alla versione 7.12
Esporta la configurazione senza dati sensibili
Incolla qua sotto tag code

Così la vedo e ti dico come aggiungere WiFi ulteriori

ora non ho accesso all'apparato, domani sera ti posto il tutto
ps scusa avevo sbagliato modello quello corretto è

Mikrotik RouterBoard hAP AC Lite

grazie mille

r3dl4nce · 15 Novembre 2023

Scusa ma perché le lite? Ha porte 100 Mbps, inutile la wifi ac... Se puoi cambiala con una hAp ac2

Maniac145 · 15 Novembre 2023

Maniac145 ha detto:
ora non ho accesso all'apparato, domani sera ti posto il tutto
grazie mille

r3dl4nce ha detto:
Scusa ma perché le lite? Ha porte 100 Mbps, inutile la wifi ac... Se puoi cambiala con una hAp ac2

lo so ma tanto come connessione internet ho una vdsl da 40 e mi fa poca differenza la avevo preso per altro scopo la riciclo come ac per uso ospiti e poco più

Maniac145 · 16 Novembre 2023

r3dl4nce ha detto:
Aggiorna alla versione 7.12
Esporta la configurazione senza dati sensibili
Incolla qua sotto tag code

Così la vedo e ti dico come aggiungere WiFi ulteriori

ecco la configurazione

Codice:

# nov/16/2023 08:06:54 by RouterOS 6.49.10
# software id = LDSN-L25I
#
# model = RB952Ui-5ac2nD
# serial number = CC460CFF401C
/interface bridge
add comment="BRIDGE LAN" name=bridge-lan
/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik
add authentication-types=wpa-psk,wpa2-psk comment="PROFILO SICUREZZA WIFI" \
    eap-methods="" mode=dynamic-keys name=profilo-wifi supplicant-identity="" \
    wpa-pre-shared-key=********** wpa2-pre-shared-key=**********
/interface wireless
set [ find default-name=wlan1 ] band=2ghz-b/g/n comment="WIFI 2.4 GHZ" \
    country=no_country_set disabled=no frequency=auto frequency-mode=\
    manual-txpower mode=ap-bridge radio-name=********** security-profile=\
    profilo-wifi ssid=********** station-roaming=enabled \
    wireless-protocol=802.11 wps-mode=disabled
set [ find default-name=wlan2 ] band=5ghz-a/n/ac channel-width=\
    20/40/80mhz-Ceee comment="WIFI 5 GHZ" country=no_country_set \
    default-forwarding=no disabled=no frequency=auto frequency-mode=\
    manual-txpower mode=ap-bridge radio-name=NOME-RETE-WIFI-5GHZ \
    security-profile=profilo-wifi ssid=******** station-roaming=enabled \
    wireless-protocol=802.11 wps-mode=disabled
/interface wireless manual-tx-power-table
set wlan1 comment="WIFI 2.4 GHZ"
set wlan2 comment="WIFI 5 GHZ"
/interface wireless nstreme
set wlan1 comment="WIFI 2.4 GHZ"
set wlan2 comment="WIFI 5 GHZ"
/user group
set full policy="local,telnet,ssh,ftp,reboot,read,write,policy,test,winbox,pas\
    sword,web,sniff,sensitive,api,romon,dude,tikapp"
/interface bridge port
add bridge=bridge-lan interface=ether1
add bridge=bridge-lan interface=ether2
add bridge=bridge-lan interface=ether3
add bridge=bridge-lan interface=ether4
add bridge=bridge-lan interface=ether5
add bridge=bridge-lan interface=wlan1
add bridge=bridge-lan interface=wlan2
/ip neighbor discovery-settings
set discover-interface-list=!dynamic
/ip address
add address=10.0.83.180/24 comment="IP LAN" interface=bridge-lan network=\
    10.0.83.0
/ip cloud
set ddns-enabled=yes update-time=no
/ip dns
set servers=10.224.16.4,10.224.16.5
/ip route
add comment="DEFAULT GW" distance=1 gateway=10.0.83.1
/ip service
set telnet disabled=yes
set ftp disabled=yes
set api disabled=yes
set api-ssl disabled=yes
/system clock
set time-zone-name=Europe/London
/system identity
set name="AP UFF PAOLO"
/system ntp client
set enabled=yes server-dns-names=ntp1.inrim.it,it.pool.ntp.org

r3dl4nce · 16 Novembre 2023

Già non ci siamo, ti ho scritto di aggiornare alla 7.12, non ho nulla rimasto con versioni 6.x quindi non posso provare la tua configurazione

# nov/16/2023 08:06:54 by RouterOS 6.49.10

Maniac145 · 16 Novembre 2023

Post unito automaticamente: 16 Novembre 2023

r3dl4nce ha detto:
Già non ci siamo, ti ho scritto di aggiornare alla 7.12, non ho nulla rimasto con versioni 6.x quindi non posso provare la tua configurazione

# nov/16/2023 08:06:54 by RouterOS 6.49.10

per il hAP ac lite TC non me la dava questa era 'ultima stabile

Post unito automaticamente: 16 Novembre 2023

r3dl4nce ha detto:
Già non ci siamo, ti ho scritto di aggiornare alla 7.12, non ho nulla rimasto con versioni 6.x quindi non posso provare la tua configurazione

# nov/16/2023 08:06:54 by RouterOS 6.49.10

che ne pesi se prendessi questo hAP ax² sarebbe molto meglio e poi magari ci ri sentiamo per la configurazione della rete ospiti?

r3dl4nce · 16 Novembre 2023

Maniac145 ha detto:
per il hAP ac lite TC non me la dava questa era 'ultima stabile

Codice:

/system package update set channel=upgrade
/system package update download
/system reboot

Maniac145 ha detto:
che ne pesi se prendessi questo hAP ax² sarebbe molto meglio e poi magari ci ri sentiamo per la configurazione della rete ospiti?

Ne ho uno qua i nditta che sto testando, i nuovi modelli ax hanno il nuovo wifiwave2 per cui la configurazione wifi è tutta diversa, ancora non li installo perché il nuovo capsman devo studiarlo, comunque per una configurazione semplice può andare bene e supporta wifi 6/ax, solo che la configurazione del wifi è tutta diversa

Maniac145 · 16 Novembre 2023

r3dl4nce ha detto:
Codice:

/system package update set channel=upgrade /system package update download /system reboot

Ne ho uno qua i nditta che sto testando, i nuovi modelli ax hanno il nuovo wifiwave2 per cui la configurazione wifi è tutta diversa, ancora non li installo perché il nuovo capsman devo studiarlo, comunque per una configurazione semplice può andare bene e supporta wifi 6/ax, solo che la configurazione del wifi è tutta diversa

ok grazie uso il codice per fare l'update e ci ri aggiorniamo, quando ho il 7.12
poi in futuro se lo cabio con il hAp ac2, immagino che la congiurazione sarà uguale

Maniac145 · 17 Novembre 2023

ecco la configurazione con il 7.12, puoi aiutarmi ad aggiungere una rete ospiti che possa accedere solo ad internet e non alla rete interna

Codice:

# 2023-11-17 07:59:40 by RouterOS 7.12
# software id = LDSN-L25I
#
# model = RB952Ui-5ac2nD
# serial number = CC460CFF401C
/interface bridge
add comment="BRIDGE LAN" name=bridge-lan
/interface lte apn
set [ find default=yes ] ip-type=ipv4 use-network-apn=no
/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik
add authentication-types=wpa-psk,wpa2-psk comment="PROFILO SICUREZZA WIFI" \
    eap-methods="" mode=dynamic-keys name=profilo-wifi supplicant-identity=""
/interface wireless
set [ find default-name=wlan1 ] band=2ghz-b/g/n comment="WIFI 2.4 GHZ" \
    country=no_country_set disabled=no frequency=auto frequency-mode=\
    manual-txpower mode=ap-bridge radio-name=******* security-profile=\
    profilo-wifi ssid=******* station-roaming=enabled \
    wireless-protocol=802.11 wps-mode=disabled
set [ find default-name=wlan2 ] band=5ghz-a/n/ac channel-width=\
    20/40/80mhz-Ceee comment="WIFI 5 GHZ" country=no_country_set \
    default-forwarding=no disabled=no frequency=auto frequency-mode=\
    manual-txpower mode=ap-bridge radio-name=NOME-RETE-WIFI-5GHZ \
    security-profile=profilo-wifi ssid=******* station-roaming=enabled \
    wireless-protocol=802.11 wps-mode=disabled
/interface wireless manual-tx-power-table
set wlan1 comment="WIFI 2.4 GHZ"
set wlan2 comment="WIFI 5 GHZ"
/interface wireless nstreme
set wlan1 comment="WIFI 2.4 GHZ"
set wlan2 comment="WIFI 5 GHZ"
/routing bgp template
set default disabled=no output.network=bgp-networks
/routing ospf instance
add disabled=no name=default-v2
/routing ospf area
add disabled=yes instance=default-v2 name=backbone-v2
/interface bridge port
add bridge=bridge-lan ingress-filtering=no interface=ether1
add bridge=bridge-lan ingress-filtering=no interface=ether2
add bridge=bridge-lan ingress-filtering=no interface=ether3
add bridge=bridge-lan ingress-filtering=no interface=ether4
add bridge=bridge-lan ingress-filtering=no interface=ether5
add bridge=bridge-lan ingress-filtering=no interface=wlan1
add bridge=bridge-lan ingress-filtering=no interface=wlan2
/ip neighbor discovery-settings
set discover-interface-list=!dynamic
/ip settings
set max-neighbor-entries=8192
/ipv6 settings
set disable-ipv6=yes max-neighbor-entries=8192
/interface ovpn-server server
set auth=sha1,md5
/ip address
add address=10.0.83.180/24 comment="IP LAN" interface=bridge-lan network=\
    10.0.83.0
/ip cloud
set ddns-enabled=yes update-time=no
/ip dns
set servers=10.224.16.4,10.224.16.5
/ip route
add comment="DEFAULT GW" disabled=no dst-address=0.0.0.0/0 gateway=10.0.83.1
/ip service
set telnet disabled=yes
set ftp disabled=yes
set api disabled=yes
set api-ssl disabled=yes
/routing bfd configuration
add disabled=no interfaces=all min-rx=200ms min-tx=200ms multiplier=5
/system clock
set time-zone-name=Europe/London
/system identity
set name="AP UFF PAOLO"
/system note
set show-at-login=no
/system ntp client
set enabled=yes
/system ntp client servers
add address=ntp1.inrim.it
add address=it.pool.ntp.org

r3dl4nce · 17 Novembre 2023

Ecco qua, devi configurare nome e password della rete ospiti, oltre al limite di banda (nella queue) DL/UP per la rete ospiti

Codice:

/interface wireless security-profiles
add authentication-types=wpa-psk,wpa2-psk comment="PROFILO WIFI OSPITI" eap-methods="" mode=dynamic-keys name=profiloOspiti supplicant-identity="" \
    wpa-pre-shared-key=PASSWORD-OSPITI wpa2-pre-shared-key=PASSWORD-OSPITI

/interface wireless
add comment="WIFI 2.4 GHZ OSPITI" disabled=no keepalive-frames=disabled master-interface=wlan1 max-station-count=50 \
    multicast-buffering=disabled name=wlan3-ospiti security-profile=profiloOspiti ssid=NOME-RETE-WIFI-OSPITI wds-cost-range=0 wds-default-cost=0  \
    wps-mode=disabled


/interface bridge
add comment="BRIDGE WIFI OSPITI" name=bridge-ospiti
/interface bridge port
add bridge=bridge-ospiti interface=wlan3-ospiti


/queue simple
add comment="LIMITE BANDA WIFI OSPITI" max-limit=4M/10M name=queueOspiti target=bridge-ospiti

/system ntp server
set enabled=yes manycast=yes


/ip address
add address=192.168.200.1/24 comment="IP SU BRIDGE OSPITI" interface=bridge-ospiti 

/ip/dns/set allow-remote-requests=yes

/ip pool
add comment="POOL DHCP WIFI OSPITI" name=poolDhcpOspiti ranges=192.168.200.100-192.168.200.149
/ip dhcp-server
add address-pool=poolDhcpOspiti comment="DHCP SERVER RETE OSPITI" interface=bridge-ospiti name=dhcpOspiti
/ip dhcp-server network
add address=192.168.200.0/24 comment="LAN OSPITI" dns-server=192.168.200.1 gateway=192.168.200.1 ntp-server=192.168.200.1


/interface list
add name=LAN
add name=LAN-OSPITI
/interface list member
add interface=bridge-lan list=LAN
add interface=bridge-ospiti list=LAN-OSPITI

/ip firewall address-list
add address=10.0.83.0/24 list=NetLan
add address=192.168.200.0/24 list=NetOspiti
/ip firewall filter
add action=accept chain=input comment="IN - ACCEPT - RETE OSPITI -> DNS" dst-port=53 in-interface-list=LAN-OSPITI protocol=udp
add action=accept chain=input comment="IN - ACCEPT - RETE OSPITI -> NTP" dst-port=123 in-interface-list=LAN-OSPITI protocol=udp
add action=drop chain=input comment="IN - DROP - RETE OSPITI -> ALTRE CONNESSIONI DA RET EOSPITI" in-interface-list=LAN-OSPITI
add action=accept chain=forward comment="FWD - ACCEPT - ACCESSO INTERNET (TRAMITE GATEWAY LAN) DA RETE OSPITI" dst-address-list=!NetLan in-interface-list=\
    LAN-OSPITI out-interface-list=LAN src-address-list=NetOspiti
add action=drop chain=forward comment="FWD - DROP - ALTRE CONNESSIONI DA RETE OSPITI" in-interface-list=LAN-OSPITI
/ip firewall nat
add action=masquerade chain=srcnat comment="SRCNAT - MASQUERADE - ACCESSO INTERNET (TRAMITE GATEWAY LAN) DA RETE OSPITI" dst-address-list=!NetLan \
    out-interface-list=LAN src-address-list=NetOspiti

Maniac145 · 17 Novembre 2023

r3dl4nce ha detto:

Ecco qua, devi configurare nome e password della rete ospiti, oltre al limite di banda (nella queue) DL/UP per la rete ospiti

Codice:

/interface wireless security-profiles
add authentication-types=wpa-psk,wpa2-psk comment="PROFILO WIFI OSPITI" eap-methods="" mode=dynamic-keys name=profiloOspiti supplicant-identity="" \
    wpa-pre-shared-key=PASSWORD-OSPITI wpa2-pre-shared-key=PASSWORD-OSPITI

/interface wireless
add comment="WIFI 2.4 GHZ OSPITI" disabled=no keepalive-frames=disabled master-interface=wlan1 max-station-count=50 \
    multicast-buffering=disabled name=wlan3-ospiti security-profile=profiloOspiti ssid=NOME-RETE-WIFI-OSPITI wds-cost-range=0 wds-default-cost=0  \
    wps-mode=disabled


/interface bridge
add comment="BRIDGE WIFI OSPITI" name=bridge-ospiti
/interface bridge port
add bridge=bridge-ospiti interface=wlan3-ospiti


/queue simple
add comment="LIMITE BANDA WIFI OSPITI" max-limit=4M/10M name=queueOspiti target=bridge-ospiti

/system ntp server
set enabled=yes manycast=yes


/ip address
add address=192.168.200.1/24 comment="IP SU BRIDGE OSPITI" interface=bridge-ospiti

/ip/dns/set allow-remote-requests=yes

/ip pool
add comment="POOL DHCP WIFI OSPITI" name=poolDhcpOspiti ranges=192.168.200.100-192.168.200.149
/ip dhcp-server
add address-pool=poolDhcpOspiti comment="DHCP SERVER RETE OSPITI" interface=bridge-ospiti name=dhcpOspiti
/ip dhcp-server network
add address=192.168.200.0/24 comment="LAN OSPITI" dns-server=192.168.200.1 gateway=192.168.200.1 ntp-server=192.168.200.1


/interface list
add name=LAN
add name=LAN-OSPITI
/interface list member
add interface=bridge-lan list=LAN
add interface=bridge-ospiti list=LAN-OSPITI

/ip firewall address-list
add address=10.0.83.0/24 list=NetLan
add address=192.168.200.0/24 list=NetOspiti
/ip firewall filter
add action=accept chain=input comment="IN - ACCEPT - RETE OSPITI -> DNS" dst-port=53 in-interface-list=LAN-OSPITI protocol=udp
add action=accept chain=input comment="IN - ACCEPT - RETE OSPITI -> NTP" dst-port=123 in-interface-list=LAN-OSPITI protocol=udp
add action=drop chain=input comment="IN - DROP - RETE OSPITI -> ALTRE CONNESSIONI DA RET EOSPITI" in-interface-list=LAN-OSPITI
add action=accept chain=forward comment="FWD - ACCEPT - ACCESSO INTERNET (TRAMITE GATEWAY LAN) DA RETE OSPITI" dst-address-list=!NetLan in-interface-list=\
    LAN-OSPITI out-interface-list=LAN src-address-list=NetOspiti
add action=drop chain=forward comment="FWD - DROP - ALTRE CONNESSIONI DA RETE OSPITI" in-interface-list=LAN-OSPITI
/ip firewall nat
add action=masquerade chain=srcnat comment="SRCNAT - MASQUERADE - ACCESSO INTERNET (TRAMITE GATEWAY LAN) DA RETE OSPITI" dst-address-list=!NetLan \
    out-interface-list=LAN src-address-list=NetOspiti

Grazie mille

Maniac145 · 9 Febbraio 2024

riapro questo post, perchè vorrei riciclare il

Mikrotik RouterBoard hAP AC Lite

come dispositivo che mi trasformi il wifi in rete ethernet per connettere 2 stampanti che non hanno il wifi @r3dl4nce saresti così gentile da aiutarmi

grazie in anticipo

Maniac145 · 10 Febbraio 2024

Maniac145 ha detto:
riapro questo post, perchè vorrei riciclare il

Mikrotik RouterBoard hAP AC Lite

come dispositivo che mi trasformi il wifi in rete ethernet per connettere 2 stampanti che non hanno il wifi @r3dl4nce saresti così gentile da aiutarmi

grazie in anticipo

risolto, grazie comunque

Cerca

DOMANDA configurare Mikrotik RouterBoard hAP AC Lite rete ospiti

Maniac145

r3dl4nce

Maniac145

Mikrotik RouterBoard hAP AC Lite

r3dl4nce

Maniac145

Maniac145

r3dl4nce

Maniac145

r3dl4nce

Maniac145

Maniac145

r3dl4nce

Maniac145

Maniac145

Mikrotik RouterBoard hAP AC Lite

Maniac145

Mikrotik RouterBoard hAP AC Lite

Ci sono discussioni simili a riguardo, dai un'occhiata!

Entra

Discussioni Simili

DOMANDA configurare Mikrotik RouterBoard hAP AC Lite rete ospiti

Mikrotik RouterBoard hAP AC Lite​

Mikrotik RouterBoard hAP AC Lite​

Mikrotik RouterBoard hAP AC Lite​

Ci sono discussioni simili a riguardo, dai un'occhiata!

Entra

Discussioni Simili

Mikrotik RouterBoard hAP AC Lite

Mikrotik RouterBoard hAP AC Lite

Mikrotik RouterBoard hAP AC Lite