# Assembly for fun for christmas time
# By A. Dureghello (C) 2024
#
# gcc -nostdlib -fno-pie -no-pie natale.s -o natale
# or
# gcc natale.s -c | ld natale.o -nostdlib -o natale
#
.global _start
.text
.macro ioctl
mov $16,%rax
syscall
.endm
.macro open
mov $2,%rax
syscall
.endm
.macro read fp,buf,len
push %rax
push %rcx
mov \fp,%rdi
mov \buf,%rsi
mov \len,%rdx
xor %rax,%rax
syscall
pop %rcx
pop %rax
.endm
.macro write fp,buf,len
push %r11
mov $1,%rax
mov \fp,%rdi
mov \buf,%rsi
mov \len,%rdx
syscall
pop %r11
.endm
.macro close fp
mov \fp,%rdi
mov $3,%rax
syscall
.endm
.macro exit val
mov $0x1,%ax
mov \val,%ebx
int $0x80
.endm
.macro nsleep s ns
push %r11
mov $35,%rax
xor %rsi,%rsi
mov $rqtp,%rdi
movq \s,(%rdi)
movq \ns,8(%rdi)
syscall
pop %r11
.endm
.macro cpz dst src
push %rsi
push %rdi
push %rbx
xor %eax,%eax
mov \src,%rsi
mov \dst,%rdi
0: cmpb $0,(%rsi)
je 1f
movb (%rsi),%bl
movb %bl,(%rdi)
inc %rsi
inc %rdi
inc %eax
jmp 0b
1: pop %rbx
pop %rdi
pop %rsi
.endm
n2s: push %rdx
push %rbx
mov $sbuf,%rdi
add $32,%rdi
movb $0,(%rdi)
dec %rdi
mov $10,%bx
0: xor %edx,%edx
div %bx
add $48,%edx
movb %dl,(%rdi)
test %ax,%ax
jz 1f
dec %rdi
jmp 0b
1: pop %rbx
pop %rdx
ret
slen: push %rsi
xor %edx,%edx
0: cmpb $0,(%rsi)
je 1f
inc %rsi
inc %edx
jmp 0b
1: pop %rsi
ret
vtpos: mov $9,%r8
call n2s
mov $vt,%rdx
cpz %rdx,%rdi
add %rax,%rdx
add %rax,%r8
movb $0x3b,(%rdx)
inc %rdx
inc %r8
mov %rbx,%rax
call n2s
cpz %rdx,%rdi
add %rax,%rdx
add %rax,%r8
movb $0x48,(%rdx)
inc %rdx
inc %r8
movb $0,(%rdx)
write $0,$cpos,%r8
ret
wr_str: call slen
mov %rsi,%rax
add %rdx,%rax
movb $0xa,(%rax)
inc %rax
movb $0,(%rax)
add $2,%edx
mov $4,%eax
mov $1,%ebx
mov %rsi,%rcx
int $0x80
ret
gpos: xor %rdx,%rdx
movw (%r10),%ax
div %r11w
movzx %dx,%rax
push %rax
xor %rdx,%rdx
movw 2(%r10),%ax
div %r12w
movzx %dx,%rbx
inc %dx
and $7,%dx
add $0x30,%dx
mov $color,%rcx
movb %dl,(%rcx)
pop %rax
call vtpos
add $4,%r10
ret
_start:
mov $urand,%rdi
mov $2,%rsi
open
mov $vbuf,%r10
push %r10
movl $8192,%ecx
0: push %rax
read %rax,%r10,$1
pop %rax
cmpb $0,(%r10)
je 0b
inc %r10
dec %ecx
cmp $0,%ecx
jne 0b
close %rax
pop %r10
mov $0,%rdi
mov $0x5413,%rsi
mov $ws,%rdx
ioctl
mov $ws,%rsi
movw (%rsi),%r11w
movw 2(%rsi),%r12w
movl $2048,%ecx
1: push %rcx
call gpos
write $0,$ch,$1
nsleep $0 $5000000
pop %rcx
dec %ecx
jnz 1b
movzx %r11w,%eax
shr $1,%eax
movzx %r12w,%ebx
shr $2,%ebx
call vtpos
mov $auguri,%rsi
call wr_str
movzx %r11w,%eax
movzx %r12w,%ebx
call vtpos
exit $0
.text
urand: .ascii "/dev/urandom"
.byte 0
.data
auguri: .byte 0x1b,0x5b,0x35,0x6d
.ascii " Buon 2025, forza Linux ! "
.byte 0,0
ch: .byte 0x2a
cpos: .byte 0x1b,0x5b,0x31,0x3b,0x33
color: .byte 0,0x6d,0x1b,0x5b
vt: .rept 32
.byte 0
.endr
.section memory,"aw",@nobits
sbuf: .rept 64
.byte 0x0
.endr
vbuf: .rept 1024*128
.byte 0x0
.endr
rqtp: .quad 0
.quad 0
ws: .word 0,0,0,0
